// Import Platform Service Interface
import com.nokia.lib.Service;

// Heading of the application
heading_txt.text = "Exporting landmarks";
 
// Create new Service object which has Landmark information
var landmark = new Service("Service.Landmarks", "IDataSource");
 
// Define Array for IDs of the landmarks
var idList:Array = new Array();
 
/**********************************************************
** Function for pressing the List button.
** Calls GetList() method synchronously.
** Method gets list of the landmarks
**********************************************************/
list_mc.onPress = function() {
 
    // Define input parameters
    var inParams = {Type:"Landmark"};
 
    // Define result value
    var outParams = landmark.GetList(inParams);
 
    // Check if getting the list success 
    if (outParams.ErrorCode == 0) {
        outList = outParams.ReturnValue;
        outputEntry = null;
        idList = [];
        text_txt.text = "";
        var i = 0;
        do {
            outputEntry = outList.next();
            if (null != outputEntry) {
                i++;
                // Get the lists of IDs and landmark information to Arrays
                idList.push(outputEntry.id);
 
                text_txt.text += "Landmark "+i+"\r"+outputEntry.LandmarkName+
                    "\r";
                } else {
                break;
            }
        } while (true);
    } else {
        // if errors trace them to the textfield
        var errorId = outParams.ErrorCode;
        text_txt.text = "Error while listing: "+errorId;
    };
};
 
/**********************************************************
** Function for pressing the Export button.
** Calls Export() method synchronously.
** Method exports listed landmarks to the file
**********************************************************/
export_mc.onPress = function() {
 
    // Define input parameters
    var inputData = {
        IdList:idList, DestinationFile:"c:\\Data\\Others\\landmarks.lmx", 
        MimeType:"application/vnd.nokia.landmarkcollection+xml"
        };
    var inParams = {Type:"Landmark", Data:inputData};
 
    // Define result value
    var outParams = landmark.Export(inParams);
    if(idList[0]) {
        if (outParams.ErrorCode == 0) {
            text_txt.text = "All landmarks exported to file";
        } else {
            var errorId2 = outParams.ErrorCode;
            text_txt.text = "Error while exporting: "+errorId2;
        };
    } else {
        text_txt.text = "No landmarks listed!" +
            "Press the List button to list all the landmarks to the input.";
    };
};